WS2812B: जादुई RGB LED पट्टी

आपल्या DIY प्रकल्पांमध्ये आपल्याला रंगाचा एक स्पर्श जोडण्याची आवश्यकता आहे. यासाठी, बरेच निर्माते प्रसिद्ध वापरतात डब्ल्यूएस 2812 बी आरजीबी एलईडी पट्ट्या, ज्यात आपल्या प्रकल्पांसाठी विविध रंग नियंत्रण आणि जोरदार आकर्षक प्रकाश प्रभाव प्राप्त करावा. निश्चितच ते अर्डिनो बोर्डांशी पूर्णपणे सुसंगत पट्ट्या आहेत, म्हणून त्यांना एकत्रित करण्याचा प्रयत्न करताना आपल्याला कोणतीही अडचण येणार नाही.

आपण त्यांना शोधू शकता लांबी 1 मीटर, उदाहरणार्थ, जरी त्यांच्याकडे असलेल्या प्रत्येक मीटरच्या एलईडीच्या घनतेच्या प्रकारानुसार ते बदलू शकतात. उदाहरणार्थ, तेथे 30 एलईडी ते 144 एलईडी आहेत. तथापि, आपल्याला मोठी पृष्ठभाग मिळविण्यासाठी अधिक लांबीची आवश्यकता असल्यास, आपल्याकडे आरजीबी एलईडी पॅनेलसारखे बाजारात इतर पर्याय देखील आहेत किंवा आपण नेहमी कित्येक पट्ट्या वापरू शकता ...

या पट्ट्या याशिवाय आणखी काही नाहीत जमलेल्या आरजीबी एलईडीची मालिका आणि त्यांना पट्ट्यामध्ये गटबद्ध करण्यासाठी सामान्य समर्थनावर बसविले. परंतु त्याचे ऑपरेशन स्वतंत्र आरजीबी एलईडीसारखेच आहे.

आरजीबी एलईडी बद्दल अधिक माहिती

डब्ल्यूएस 2812 बी म्हणजे काय?

वास्तविक डब्ल्यूएस 2812 बी ही पट्टीच नाही तर प्रत्येकाची आहे पेशी किंवा लहान आरजीबी एलईडी प्लेट्स ज्यात समाविष्ट आहे. त्यास पट्टी किंवा पॅनेलच्या रूपात गटबद्ध केले जाऊ शकते, जेणेकरून आपण त्यांची संख्या आणि आकारानुसार विविध कॉन्फिगरेशन बनवू शकता. बनवलेल्या पट्ट्या लवचिक पट्ट्या असतात, परंतु पीसीबी पॅनेलवर आपण डब्ल्यूएस 2812 बी देखील शोधू शकता.

आपण इच्छित असल्यास, आपण डिव्हाइस शोधू शकता स्वतंत्रपणे डब्ल्यूएस 2812 बी आपल्याला स्वतःला आवश्यक आकार तयार करण्यासाठी. उदाहरणार्थ, त्यापैकी सुमारे 100 युनिट्सची किंमत सामान्यत: 10 डॉलर्सपेक्षा थोडी जास्त असते.

आपण त्यांना फेकून दिले हे देखील आपल्याला माहित असले पाहिजे आपण त्यांना कापू शकता आपल्याला जिथे जिथे गरज असेल तेथे कात्री लावून ते कार्य करणे थांबवितात असे होत नाही. तर आपल्याकडे आपल्यास आवश्यक असलेले केवळ आरजीबी एलईडी असू शकतात. खरं तर, यात काही चिन्हे (तीन तांबे पॅड्स) आहेत ज्या आपण कापू शकता. जर आपण या पॅड्स कापल्या तर आपल्याकडे पट्टीच्या एका बाजूला तीन ट्रॅक असतील आणि दुसर्‍या तुकड्यांचा पुन्हा वापर करायचा असेल तर त्यामध्ये सोपी कनेक्शनसाठी पिन सोल्डर करू शकता.

पिनआउट आणि डेटाशीट

हा एक स्वतंत्र डब्ल्यूएस 2812 बी सेल आहे ज्याची माहिती आणि आऊटपुट आहे

आपल्या बद्दल अधिक माहितीसाठी आरजीबी एलईडी पट्टी डब्ल्यूएस 2812 बी आपण वाचू शकता डेटाशीट प्रत्येक निर्मात्याद्वारे ऑफर केलेले, तेथे सर्व परिचालन श्रेणी आणि मर्यादा जाणून घेण्याव्यतिरिक्त, त्यांचा योग्यरितीने वापर कसा करावा हे जाणून घेण्यासाठी परिमाण आणि तांत्रिक वैशिष्ट्यांच्या सर्व तपशीलांचा सल्ला घेऊ शकता.

डब्ल्यूएस 2812 बी डेटाशीट डाउनलोड करा

साठी म्हणून पिनआउटएकतर ही एक मोठी समस्या नाही, या पट्ट्यामध्ये एक साधा कनेक्शन आहे जो आपण सुरुवातीपासूनच जास्त माहितीशिवाय मास्टर करू शकता. फक्त तीनच उपलब्ध आहेत, जरी प्रत्येक डब्ल्यूएस २2812२ बी बी सेलमध्ये अधिक कनेक्शन आहेत ...

आपण फक्त पाहिजे कनेक्ट करा प्रत्येक पट्टीवर व्हीसीसी पिन जी अर्दूनो पासून वेगळ्या वीज पुरवठ्यापासून 5V ला पट्टी फीड करते, जीएनडी ग्राउंड, अर्थातच, आणि शेवटी डीआयआय जी सक्रिय आहे मायक्रोकंट्रोलरच्या कोणत्याही आउटपुटवर जाईल पट्टीवरील आरजीबी एलईडी.

बघितले तर एक डब्ल्यूएस 2812 बी सेल आपल्याला दिसेल की त्यात डेटा इन किंवा डीआय इनपुट आणि व्हीसीसी आणि जीएनडी वीजपुरवठा आहे. मग त्यात आणखी तीन आऊटपुट असतील, त्या स्ट्रिपच्या पुढील सेलशी जोडल्या जातील आणि पुढच्या सेलमध्ये त्याचे आउटपुट पुढील पट्ट्याच्या अखंड इनपुटशी जोडले जातील आणि संपूर्ण पट्टी पूर्ण होईपर्यंत ...

हे तंतोतंत आहे डीआय किंवा डेटा इनपुट आरजीबी एलईडी कॉन्फिगर करणे मनोरंजक आहे आणि तीच डेटा आऊट किंवा डीओशी कनेक्ट केली जाईल जी तीच माहिती पट्टीच्या पुढील दुव्यावर घेऊन जाईल. आणि म्हणून ती संपूर्ण पट्टीवर पसरते.

डब्ल्यूएस 2812 बी आरजीबी एलईडी पट्ट्या खरेदी करा

आपण हे करू शकता खूप जास्त किंमतीत खरेदी करा विविध विशेष स्टोअरमध्ये. आपल्याकडे देखील ते अ‍ॅमेझॉनमध्ये भिन्न स्वरूपात आहेत. काही उदाहरणे अशीः

अर्दूनो आणि डब्ल्यूएस 2812 बी सह चाचणी घेत आहे

जसे आपण कल्पना करू शकता, केवळ तीन पिनसह हे करणे सोपे आहे अर्दूनोशी कनेक्ट व्हा जसे आपण वरील आकृतीमध्ये पाहू शकता. आपल्याला फक्त 5v आणि जीएनडीला डब्ल्यूएस 2812 बी पट्टीशी जोडायचे आहे, आणि डीआरओ आपल्याला आर्डूनोवर इच्छित आउटपुटशी जोडावे लागेल. लक्षात ठेवा आपण पिन बदलल्यास आपण स्त्रोत कोड देखील सुधारित करणे आवश्यक आहे जेणेकरून प्रोग्राम योग्य प्रकारे कार्य करेल.

लायब्ररी वापरली गेली आहे फास्ट-एलईडी मास्टर गोष्टी सुलभ करण्यासाठी आणि आरजीबी एलईडी चालविण्यास सोपी कार्ये मिळविण्यासाठी. ते डाउनलोड करण्यासाठी आणि अर्दूनो आयडीईमध्ये योग्यरित्या समाकलित करण्यासाठी, त्या दुव्यावरुन फक्त लायब्ररी डाउनलोड करा, त्यानंतर झिप अनझिप करा आणि अनझिप केलेली निर्देशिका किंवा फोल्डरला फास्टलेड असे नाव द्या, आणि त्या फोल्डरला आपल्या स्थापनेत आर्डुइनो आयडीई लायब्ररी स्थापित केलेल्या ठिकाणी हलवा. . नंतर अर्दूनो आयडीई पुन्हा उघडा आणि ते तयार होईल ...

साठी म्हणून स्केच कोड, खालील कोड प्रमाणे हे अगदी सोपे असू शकते. आपण कॉपी आणि पेस्ट करू इच्छित नसल्यास, आधीपासून आलेल्या उदाहरणांमधून आपण ते शोधू शकता. तर फाईल> उदाहरणे> फास्टलेड> कलरपलेटवर जा.

पिन 14 उदाहरणातून 5 मध्ये बदलणे लक्षात ठेवा जे मी आकृतीमध्ये वापरलेले आहे. किंवा आपण पिन 14 शी कनेक्ट होऊ शकता आणि कोड सुधारित करणे टाळू शकता. जसे आपण पसंत करता.

#include <FastLED.h>

#define LED_PIN     5
#define NUM_LEDS    14
#define BRIGHTNESS  64
#define LED_TYPE    WS2811
#define COLOR_ORDER GRB
CRGB leds[NUM_LEDS];

#define UPDATES_PER_SECOND 100

// This example shows several ways to set up and use 'palettes' of colors
// with FastLED.
//
// These compact palettes provide an easy way to re-colorize your
// animation on the fly, quickly, easily, and with low overhead.
//
// USING palettes is MUCH simpler in practice than in theory, so first just
// run this sketch, and watch the pretty lights as you then read through
// the code.  Although this sketch has eight (or more) different color schemes,
// the entire sketch compiles down to about 6.5K on AVR.
//
// FastLED provides a few pre-configured color palettes, and makes it
// extremely easy to make up your own color schemes with palettes.
//
// Some notes on the more abstract 'theory and practice' of
// FastLED compact palettes are at the bottom of this file.



CRGBPalette16 currentPalette;
TBlendType    currentBlending;

extern CRGBPalette16 myRedWhiteBluePalette;
extern const TProgmemPalette16 myRedWhiteBluePalette_p PROGMEM;


void setup() {
    delay( 3000 ); // power-up safety delay
    FastLED.addLeds<LED_TYPE, LED_PIN, COLOR_ORDER>(leds, NUM_LEDS).setCorrection( TypicalLEDStrip );
    FastLED.setBrightness(  BRIGHTNESS );
    
    currentPalette = RainbowColors_p;
    currentBlending = LINEARBLEND;
}


void loop()
{
    ChangePalettePeriodically();
    
    static uint8_t startIndex = 0;
    startIndex = startIndex + 1; /* motion speed */
    
    FillLEDsFromPaletteColors( startIndex);
    
    FastLED.show();
    FastLED.delay(1000 / UPDATES_PER_SECOND);
}

void FillLEDsFromPaletteColors( uint8_t colorIndex)
{
    uint8_t brightness = 255;
    
    for( int i = 0; i < NUM_LEDS; i++) {
        leds[i] = ColorFromPalette( currentPalette, colorIndex, brightness, currentBlending);
        colorIndex += 3;
    }
}


// There are several different palettes of colors demonstrated here.
//
// FastLED provides several 'preset' palettes: RainbowColors_p, RainbowStripeColors_p,
// OceanColors_p, CloudColors_p, LavaColors_p, ForestColors_p, and PartyColors_p.
//
// Additionally, you can manually define your own color palettes, or you can write
// code that creates color palettes on the fly.  All are shown here.

void ChangePalettePeriodically()
{
    uint8_t secondHand = (millis() / 1000) % 60;
    static uint8_t lastSecond = 99;
    
    if( lastSecond != secondHand) {
        lastSecond = secondHand;
        if( secondHand ==  0)  { currentPalette = RainbowColors_p;         currentBlending = LINEARBLEND; }
        if( secondHand == 10)  { currentPalette = RainbowStripeColors_p;   currentBlending = NOBLEND;  }
        if( secondHand == 15)  { currentPalette = RainbowStripeColors_p;   currentBlending = LINEARBLEND; }
        if( secondHand == 20)  { SetupPurpleAndGreenPalette();             currentBlending = LINEARBLEND; }
        if( secondHand == 25)  { SetupTotallyRandomPalette();              currentBlending = LINEARBLEND; }
        if( secondHand == 30)  { SetupBlackAndWhiteStripedPalette();       currentBlending = NOBLEND; }
        if( secondHand == 35)  { SetupBlackAndWhiteStripedPalette();       currentBlending = LINEARBLEND; }
        if( secondHand == 40)  { currentPalette = CloudColors_p;           currentBlending = LINEARBLEND; }
        if( secondHand == 45)  { currentPalette = PartyColors_p;           currentBlending = LINEARBLEND; }
        if( secondHand == 50)  { currentPalette = myRedWhiteBluePalette_p; currentBlending = NOBLEND;  }
        if( secondHand == 55)  { currentPalette = myRedWhiteBluePalette_p; currentBlending = LINEARBLEND; }
    }
}

// This function fills the palette with totally random colors.
void SetupTotallyRandomPalette()
{
    for( int i = 0; i < 16; i++) {
        currentPalette[i] = CHSV( random8(), 255, random8());
    }
}

// This function sets up a palette of black and white stripes,
// using code.  Since the palette is effectively an array of
// sixteen CRGB colors, the various fill_* functions can be used
// to set them up.
void SetupBlackAndWhiteStripedPalette()
{
    // 'black out' all 16 palette entries...
    fill_solid( currentPalette, 16, CRGB::Black);
    // and set every fourth one to white.
    currentPalette[0] = CRGB::White;
    currentPalette[4] = CRGB::White;
    currentPalette[8] = CRGB::White;
    currentPalette[12] = CRGB::White;
    
}

// This function sets up a palette of purple and green stripes.
void SetupPurpleAndGreenPalette()
{
    CRGB purple = CHSV( HUE_PURPLE, 255, 255);
    CRGB green  = CHSV( HUE_GREEN, 255, 255);
    CRGB black  = CRGB::Black;
    
    currentPalette = CRGBPalette16(
                                   green,  green,  black,  black,
                                   purple, purple, black,  black,
                                   green,  green,  black,  black,
                                   purple, purple, black,  black );
}


// This example shows how to set up a static color palette
// which is stored in PROGMEM (flash), which is almost always more
// plentiful than RAM.  A static PROGMEM palette like this
// takes up 64 bytes of flash.
const TProgmemPalette16 myRedWhiteBluePalette_p PROGMEM =
{
    CRGB::Red,
    CRGB::Gray, // 'white' is too bright compared to red and blue
    CRGB::Blue,
    CRGB::Black,
    
    CRGB::Red,
    CRGB::Gray,
    CRGB::Blue,
    CRGB::Black,
    
    CRGB::Red,
    CRGB::Red,
    CRGB::Gray,
    CRGB::Gray,
    CRGB::Blue,
    CRGB::Blue,
    CRGB::Black,
    CRGB::Black
};



// Additionl notes on FastLED compact palettes:
//
// Normally, in computer graphics, the palette (or "color lookup table")
// has 256 entries, each containing a specific 24-bit RGB color.  You can then
// index into the color palette using a simple 8-bit (one byte) value.
// A 256-entry color palette takes up 768 bytes of RAM, which on Arduino
// is quite possibly "too many" bytes.
//
// FastLED does offer traditional 256-element palettes, for setups that
// can afford the 768-byte cost in RAM.
//
// However, FastLED also offers a compact alternative.  FastLED offers
// palettes that store 16 distinct entries, but can be accessed AS IF
// they actually have 256 entries; this is accomplished by interpolating
// between the 16 explicit entries to create fifteen intermediate palette
// entries between each pair.
//
// So for example, if you set the first two explicit entries of a compact 
// palette to Green (0,255,0) and Blue (0,0,255), and then retrieved 
// the first sixteen entries from the virtual palette (of 256), you'd get
// Green, followed by a smooth gradient from green-to-blue, and then Blue.

टिप्पणी करणारे सर्वप्रथम व्हा

आपली टिप्पणी द्या उत्तर रद्द करा

आपला ई-मेल पत्ता प्रकाशित केला जाणार नाही. आवश्यक फील्ड चिन्हांकित केले आहेत *

टिप्पणी *

नाव*

Correo electrónico*

मी स्वीकारतो गोपनीयता अटी*

डेटा जबाबदार: मिगुएल Áन्गल गॅटन
डेटाचा उद्देशः नियंत्रण स्पॅम, टिप्पणी व्यवस्थापन.
कायदे: आपली संमती
डेटा संप्रेषण: कायदेशीर बंधन वगळता डेटा तृतीय पक्षास कळविला जाणार नाही.
डेटा संग्रहण: ओकेन्टस नेटवर्क (EU) द्वारा होस्ट केलेला डेटाबेस
अधिकारः कोणत्याही वेळी आपण आपली माहिती मर्यादित, पुनर्प्राप्त आणि हटवू शकता.

मला वृत्तपत्र प्राप्त करायचे आहे

Hardwarelibre

डब्ल्यूएस 2812 बी: जादुई आरजीबी एलईडी पट्टी

डब्ल्यूएस 2812 बी म्हणजे काय?

पिनआउट आणि डेटाशीट

डब्ल्यूएस 2812 बी आरजीबी एलईडी पट्ट्या खरेदी करा

अर्दूनो आणि डब्ल्यूएस 2812 बी सह चाचणी घेत आहे

आपली टिप्पणी द्या उत्तर रद्द करा